3 Cortex-M3 指令集
处理器实现了 Thumb 指令集的一个版本。表 20 列出了所支持的指令。
3.1指令集汇总
在表 20 中:
- 尖括号 <> 包裹操作数的可选形式;
- 大括号 {} 包裹可省略的操作数;
- “操作数”一列并不穷举全部形式;
- Op2 表示灵活的第二操作数,可以是寄存器或常数;
- 多数指令可加可选的条件码后缀。
关于指令与操作数的更多信息,见各条指令的说明。
| 助记符 | 操作数 | 简要说明 | 影响标志 | 详见 |
|---|---|---|---|---|
| ADC, ADCS | {Rd,} Rn, Op2 | 带进位加法 | N,Z,C,V | 3.5.1 |
| ADD, ADDS | {Rd,} Rn, Op2 | 加法 | N,Z,C,V | 3.5.1 |
| ADD, ADDW | {Rd,} Rn, #imm12 | 加法 | N,Z,C,V | 3.5.1 |
| ADR | Rd, label | 装载 PC 相对地址 | - | 3.4.1 |
| AND, ANDS | {Rd,} Rn, Op2 | 逻辑与 | N,Z,C | 3.5.2 |
| ASR, ASRS | Rd, Rm, <Rs|#n> | 算术右移 | N,Z,C | 3.5.3 |
| B | label | 分支 | - | 3.8.4 |
| BFC | Rd, #lsb, #width | 位域清零 | - | 3.8.1 |
| BFI | Rd, Rn, #lsb, #width | 位域插入 | - | 3.8.1 |
| BIC, BICS | {Rd,} Rn, Op2 | 位清除 | N,Z,C | 3.5.2 |
| BKPT | #imm | 断点 | - | 3.9.1 |
| BL | label | 带链接分支 | - | 3.8.4 |
| BLX | Rm | 带链接的间接分支 | - | 3.8.4 |
| BX | Rm | 间接分支 | - | 3.8.4 |
| CBNZ | Rn, label | 比较,非零则分支 | - | 3.8.5 |
| CBZ | Rn, label | 比较,为零则分支 | - | 3.8.5 |
| CLREX | - | 清除独占标记 | - | 3.4.9 |
| CLZ | Rd, Rm | 前导零计数 | - | 3.5.4 |
| CMN, CMNS | Rn, Op2 | 比较取负 | N,Z,C,V | 3.5.5 |
| CMP, CMPS | Rn, Op2 | 比较 | N,Z,C,V | 3.5.5 |
| CPSID | iflags | 改变处理器状态,禁止中断 | - | 3.9.2 |
| CPSIE | iflags | 改变处理器状态,使能中断 | - | 3.9.2 |
| DMB | - | 数据存储屏障 | - | 3.9.3 |
| DSB | - | 数据同步屏障 | - | 3.9.4 |
| EOR, EORS | {Rd,} Rn, Op2 | 异或 | N,Z,C | 3.5.2 |
| ISB | - | 指令同步屏障 | - | 3.9.5 |
| IT | - | If-Then 条件块 | - | 3.8.6 |
| LDM | Rn{!}, reglist | 多寄存器装载,访问后递增 | - | 3.4.6 |
| LDMDB, LDMEA | Rn{!}, reglist | 多寄存器装载,访问前递减 | - | 3.4.6 |
| LDMFD, LDMIA | Rn{!}, reglist | 多寄存器装载,访问后递增 | - | 3.4.6 |
| LDR | Rt, [Rn, #offset] | 装载字 | - | 3.4.2 |
| LDRB, LDRBT | Rt, [Rn, #offset] | 装载字节 | - | 3.4.2 |
| LDRD | Rt, Rt2, [Rn, #offset] | 装载两个字 | - | 3.4.2 |
| LDREX | Rt, [Rn, #offset] | 独占装载字 | - | 3.4.8 |
| LDREXB | Rt, [Rn] | 独占装载字节 | - | 3.4.8 |
| LDREXH | Rt, [Rn] | 独占装载半字 | - | 3.4.8 |
| LDRH, LDRHT | Rt, [Rn, #offset] | 装载半字 | - | 3.4.2 |
| LDRSB, LDRSBT | Rt, [Rn, #offset] | 装载有符号字节 | - | 3.4.2 |
| LDRSH, LDRSHT | Rt, [Rn, #offset] | 装载有符号半字 | - | 3.4.2 |
| LDRT | Rt, [Rn, #offset] | 非特权装载字 | - | 3.4.4 |
| LSL, LSLS | Rd, Rm, <Rs|#n> | 逻辑左移 | N,Z,C | 3.5.3 |
| LSR, LSRS | Rd, Rm, <Rs|#n> | 逻辑右移 | N,Z,C | 3.5.3 |
| MLA | Rd, Rn, Rm, Ra | 乘加,32 位结果 | - | 3.6.1 |
| MLS | Rd, Rn, Rm, Ra | 乘减,32 位结果 | - | 3.6.1 |
| MOV, MOVS | Rd, Op2 | 传送 | N,Z,C | 3.5.6 |
| MOVT | Rd, #imm16 | 传送高半字 | - | 3.5.7 |
| MOVW, MOV | Rd, #imm16 | 传送 16 位常数 | N,Z,C | 3.5.6 |
| MRS | Rd, spec_reg | 特殊寄存器传送到通用寄存器 | - | 3.9.6 |
| MSR | spec_reg, Rm | 通用寄存器传送到特殊寄存器 | N,Z,C,V | 3.9.7 |
| MUL, MULS | {Rd,} Rn, Rm | 乘法,32 位结果 | N,Z | 3.6.1 |
| MVN, MVNS | Rd, Op2 | 传送取反 | N,Z,C | 3.5.6 |
| NOP | - | 空操作 | - | 3.9.8 |
| ORN, ORNS | {Rd,} Rn, Op2 | 逻辑或非 | N,Z,C | 3.5.2 |
| ORR, ORRS | {Rd,} Rn, Op2 | 逻辑或 | N,Z,C | 3.5.2 |
| POP | reglist | 从堆栈弹出寄存器 | - | 3.4.7 |
| PUSH | reglist | 把寄存器压入堆栈 | - | 3.4.7 |
| RBIT | Rd, Rn | 位序反转 | - | 3.5.8 |
| REV | Rd, Rn | 反转字内的字节序 | - | 3.5.8 |
| REV16 | Rd, Rn | 反转每个半字内的字节序 | - | 3.5.8 |
| REVSH | Rd, Rn | 反转低半字字节序并符号扩展 | - | 3.5.8 |
| ROR, RORS | Rd, Rm, <Rs|#n> | 循环右移 | N,Z,C | 3.5.3 |
| RRX, RRXS | Rd, Rm | 带扩展的循环右移一位 | N,Z,C | 3.5.3 |
| RSB, RSBS | {Rd,} Rn, Op2 | 反向减法 | N,Z,C,V | 3.5.1 |
| SBC, SBCS | {Rd,} Rn, Op2 | 带借位减法 | N,Z,C,V | 3.5.1 |
| SBFX | Rd, Rn, #lsb, #width | 有符号位域提取 | - | 3.8.2 |
| SDIV | {Rd,} Rn, Rm | 有符号除法 | - | 3.6.3 |
| SEV | - | 发送事件 | - | 3.9.9 |
| SMLAL | RdLo, RdHi, Rn, Rm | 有符号长乘加(32×32 + 64),64 位结果 | - | 3.6.2 |
| SMULL | RdLo, RdHi, Rn, Rm | 有符号长乘(32×32),64 位结果 | - | 3.6.2 |
| SSAT | Rd, #n, Rm {,shift #s} | 有符号饱和 | Q | 3.7.1 |
| STM | Rn{!}, reglist | 多寄存器存储,访问后递增 | - | 3.4.6 |
| STMDB, STMEA | Rn{!}, reglist | 多寄存器存储,访问前递减 | - | 3.4.6 |
| STMFD, STMIA | Rn{!}, reglist | 多寄存器存储,访问后递增 | - | 3.4.6 |
| STR | Rt, [Rn, #offset] | 存储字 | - | 3.4.2 |
| STRB, STRBT | Rt, [Rn, #offset] | 存储字节 | - | 3.4.2 |
| STRD | Rt, Rt2, [Rn, #offset] | 存储两个字 | - | 3.4.2 |
| STREX | Rd, Rt, [Rn, #offset] | 独占存储字 | - | 3.4.8 |
| STREXB | Rd, Rt, [Rn] | 独占存储字节 | - | 3.4.8 |
| STREXH | Rd, Rt, [Rn] | 独占存储半字 | - | 3.4.8 |
| STRH, STRHT | Rt, [Rn, #offset] | 存储半字 | - | 3.4.2 |
| STRT | Rt, [Rn, #offset] | 非特权存储字 | - | 3.4.4 |
| SUB, SUBS | {Rd,} Rn, Op2 | 减法 | N,Z,C,V | 3.5.1 |
| SUB, SUBW | {Rd,} Rn, #imm12 | 减法 | N,Z,C,V | 3.5.1 |
| SVC | #imm | 管理程序调用 | - | 3.9.10 |
| SXTB | {Rd,} Rm {,ROR #n} | 字节符号扩展 | - | 3.8.3 |
| SXTH | {Rd,} Rm {,ROR #n} | 半字符号扩展 | - | 3.8.3 |
| TBB | [Rn, Rm] | 表分支(字节) | - | 3.8.7 |
| TBH | [Rn, Rm, LSL #1] | 表分支(半字) | - | 3.8.7 |
| TEQ | Rn, Op2 | 等价测试 | N,Z,C | 3.5.9 |
| TST | Rn, Op2 | 位测试 | N,Z,C | 3.5.9 |
| UBFX | Rd, Rn, #lsb, #width | 无符号位域提取 | - | 3.8.2 |
| UDIV | {Rd,} Rn, Rm | 无符号除法 | - | 3.6.3 |
| UMLAL | RdLo, RdHi, Rn, Rm | 无符号长乘加(32×32 + 64),64 位结果 | - | 3.6.2 |
| UMULL | RdLo, RdHi, Rn, Rm | 无符号长乘(32×32),64 位结果 | - | 3.6.2 |
| USAT | Rd, #n, Rm {,shift #s} | 无符号饱和 | Q | 3.7.1 |
| UXTB | {Rd,} Rm {,ROR #n} | 字节零扩展 | - | 3.8.3 |
| UXTH | {Rd,} Rm {,ROR #n} | 半字零扩展 | - | 3.8.3 |
| WFE | - | 等待事件 | - | 3.9.11 |
| WFI | - | 等待中断 | - | 3.9.12 |
3.2内联函数
ANSI C 无法直接访问部分 Cortex-M3 指令。本节介绍 CMSIS 提供的、C 编译器也可能提供的内联函数,用于生成这些指令。如果 C 编译器不支持相应的内联函数,可能需要使用内联汇编器来访问某些指令。
CMSIS 提供表 21 所列的内联函数,用于生成 ANSI 无法直接访问的指令。
| 指令 | CMSIS 内联函数 |
|---|---|
| CPSIE I | void __enable_irq(void) |
| CPSID I | void __disable_irq(void) |
| CPSIE F | void __enable_fault_irq(void) |
| CPSID F | void __disable_fault_irq(void) |
| ISB | void __ISB(void) |
| DSB | void __DSB(void) |
| DMB | void __DMB(void) |
| REV | uint32_t __REV(uint32_t int value) |
| REV16 | uint32_t __REV16(uint32_t int value) |
| REVSH | uint32_t __REVSH(uint32_t int value) |
| RBIT | uint32_t __RBIT(uint32_t int value) |
| SEV | void __SEV(void) |
| WFE | void __WFE(void) |
| WFI | void __WFI(void) |
CMSIS 还提供若干使用 MRS、MSR 指令访问特殊寄存器的函数,见表 22。
| 特殊寄存器 | 访问方式 | CMSIS 函数 |
|---|---|---|
| PRIMASK | 读 | uint32_t __get_PRIMASK(void) |
| 写 | void __set_PRIMASK(uint32_t value) | |
| FAULTMASK | 读 | uint32_t __get_FAULTMASK(void) |
| 写 | void __set_FAULTMASK(uint32_t value) | |
| BASEPRI | 读 | uint32_t __get_BASEPRI(void) |
| 写 | void __set_BASEPRI(uint32_t value) | |
| CONTROL | 读 | uint32_t __get_CONTROL(void) |
| 写 | void __set_CONTROL(uint32_t value) | |
| MSP | 读 | uint32_t __get_MSP(void) |
| 写 | void __set_MSP(uint32_t TopOfMainStack) | |
| PSP | 读 | uint32_t __get_PSP(void) |
| 写 | void __set_PSP(uint32_t TopOfProcStack) |
3.3关于指令描述
以下各节给出使用指令的更多信息:
- 操作数
- 使用 PC 或 SP 的限制
- 灵活的第二操作数
- 移位操作
- 地址对齐
- PC 相对表达式
- 条件执行
- 指令宽度选择
3.3.1操作数
指令的操作数可以是 Arm 寄存器、常数,或该指令专用的其他参数。指令对操作数进行运算,通常把结果存入目的寄存器。当指令中带有目的寄存器时,它通常写在操作数之前。
某些指令的操作数是灵活的,既可写作寄存器,也可写作常数(见“灵活的第二操作数”)。
3.3.2使用 PC 或 SP 的限制
许多指令对能否把程序计数器(PC)或堆栈指针(SP)用作操作数或目的寄存器有限制,详见各条指令的说明。
用 BX、BLX、LDM、LDR 或 POP 指令写入 PC 的任何地址,其 bit[0] 必须为 1 才能正确执行 —— 该位指示所需的指令集,而 Cortex-M3 处理器只支持 Thumb 指令。
3.3.3灵活的第二操作数
许多通用数据处理指令具有灵活的第二操作数,在各指令的语法描述中记作 operand2。operand2 可以是:
- 常数;
- 带可选移位的寄存器。
常数
以 #constant 的形式给出 operand2 常数,其中 constant 可以是:
- 任何可以通过把 8 位值在 32 位字内左移任意位数得到的常数;
- 任何形如 0x00XY00XY 的常数;
- 任何形如 0xXY00XY00 的常数;
- 任何形如 0xXYXYXYXY 的常数。
上述形式中 X、Y 为十六进制数字。此外,少数指令的 constant 可取更宽的范围,这将在各条指令的说明中给出。
当 operand2 常数与 MOVS、MVNS、ANDS、ORRS、ORNS、EORS、BICS、TEQ 或 TST 指令一起使用,且该常数大于 255 并能由 8 位值移位得到时,进位标志更新为该常数的 bit[31]。若 operand2 是其他常数,这些指令不影响进位标志。
指令替换。当你指定的常数不被允许时,汇编器可能生成等价的指令。例如,汇编器可能把 CMP Rd, #0xFFFFFFFE 汇编成等价指令 CMN Rd, #0x2。
带可选移位的寄存器
以 Rm {, shift} 的形式给出 operand2 寄存器,其中:
Rm是保存第二操作数数据的寄存器;shift是对 Rm 施加的可选移位,可以是:
ASR #n :算术右移 n 位,1 ≤ n ≤ 32 LSL #n :逻辑左移 n 位,1 ≤ n ≤ 31 LSR #n :逻辑右移 n 位,1 ≤ n ≤ 32 ROR #n :循环右移 n 位,1 ≤ n ≤ 31 RRX :带扩展的循环右移一位 — :省略时不做移位,等效于 LSL #0
若省略移位,或指定 LSL #0,指令使用 Rm 中的值。若指定了移位,则对 Rm 中的值施加移位,指令使用得到的 32 位结果,而 Rm 寄存器的内容保持不变。指定带移位的寄存器与某些指令配合使用时,还会更新进位标志。关于移位操作及其对进位标志的影响,见 3.3.4 节“移位操作”。
3.3.4移位操作
寄存器移位操作把寄存器中的位向左或向右移动指定的位数(移位长度)。寄存器移位可由下列方式执行:
- 由 ASR、LSR、LSL、ROR、RRX 指令直接执行,结果写入目的寄存器;
- 由把第二操作数指定为“带移位寄存器”的指令在计算 operand2 时进行,结果供该指令使用。
允许的移位长度取决于移位类型与指令(见各条指令说明或“灵活的第二操作数”)。若移位长度为 0,则不发生移位。除移长度为 0 的情形外,寄存器移位操作都会更新进位标志。下文用 Rm 表示待移位的寄存器,n 表示移位长度。
ASR
算术右移 n 位,把寄存器 Rm 左侧的 32−n 位右移 n 位到结果的右侧 32−n 位,并把 Rm 原来的 bit[31] 复制到结果的左侧 n 位。
可用 ASR #n 把 Rm 中的值除以 2n,结果向负无穷方向取整。
当指令为 ASRS,或 ASR #n 作为 operand2 与 MOVS、MVNS、ANDS、ORRS、ORNS、EORS、BICS、TEQ 或 TST 配合使用时,进位标志更新为最后移出的位,即 Rm 的 bit[n−1]。
注:若 n 为 32 或更大,结果的所有位都置为 Rm 的 bit[31];若 n 为 32 或更大且更新进位标志,则进位标志更新为 Rm 的 bit[31]。
LSR
逻辑右移 n 位,把 Rm 左侧的 32−n 位右移到结果的右侧 32−n 位,并把结果左侧的 n 位清 0。
若把值视为无符号整数,可用 LSR #n 把 Rm 中的值除以 2n。
当指令为 LSRS,或 LSR #n 作为 operand2 与上述指令配合时,进位标志更新为最后移出的位,即 Rm 的 bit[n−1]。
注:若 n 为 32 或更大,结果所有位清 0;若 n 为 33 或更大且更新进位标志,则进位标志更新为 0。
LSL
逻辑左移 n 位,把 Rm 右侧的 32−n 位左移到结果的左侧 32−n 位,并把结果右侧的 n 位清 0。
若把值视为无符号整数或二进制补码有符号整数,可用 LSL #n 把 Rm 中的值乘以 2n。溢出可能在没有提示的情况下发生。
当指令为 LSLS,或 LSL #n(n 非零)作为 operand2 与上述指令配合时,进位标志更新为最后移出的位,即 Rm 的 bit[32−n]。与 LSL #0 配合时这些指令不影响进位标志。
注:若 n 为 32 或更大,结果所有位清 0;若 n 为 33 或更大且更新进位标志,则进位标志更新为 0。
ROR
循环右移 n 位,把 Rm 左侧的 32−n 位右移到结果的右侧 32−n 位,同时把 Rm 右侧的 n 位移到结果的左侧 n 位。
当指令为 RORS,或 ROR #n 作为 operand2 与上述指令配合时,进位标志更新为最后循环移出的位,即 Rm 的 bit[n−1]。
注:若 n 为 32,结果与 Rm 中的值相同;若更新进位标志,则更新为 Rm 的 bit[31]。移位长度 n 大于 32 的 ROR 等效于移位长度 n−32 的 ROR。
RRX
带扩展的循环右移把 Rm 中的位右移一位,并把进位标志复制到结果的 bit[31]。
当指令为 RRXS,或 RRX 作为 operand2 与上述指令配合时,进位标志更新为 Rm 的 bit[0]。
3.3.5地址对齐
对齐访问是指:字、双字或多字访问使用字对齐地址,半字访问使用半字对齐地址。字节访问总是对齐的。
Cortex-M3 处理器只对下列指令支持非对齐访问:
- LDR、LDRT
- LDRH、LDRHT
- LDRSH、LDRSHT
- STR、STRT
- STRH、STRHT
其他所有装载、存储指令若执行非对齐访问,都会产生用法故障异常,因此其访问必须地址对齐。关于用法故障的更多信息,见第 39 页的“故障处理”。
非对齐访问通常比对齐访问慢,此外某些存储器区域可能不支持非对齐访问。因此 Arm 建议程序员确保访问是对齐的。为避免意外产生非对齐访问,可用配置与控制寄存器中的 UNALIGN_TRP 位捕获所有非对齐访问,见第 137 页的“配置与控制寄存器(SCB_CCR)”。
3.3.6PC 相对表达式
PC 相对表达式或标签,是表示某条指令或字面数据地址的符号。在指令中它表示为 PC 值加上或减去一个数值偏移。汇编器根据标签与当前指令的地址计算所需偏移;若偏移过大,汇编器会报错。
- 对 B、BL、CBNZ、CBZ 指令,PC 的值是当前指令地址加 4 字节;
- 对其他使用标签的指令,PC 的值是当前指令地址加 4 字节,并把结果的 bit[1] 清 0 以使其字对齐;
- 汇编器可能允许 PC 相对表达式的其他写法,例如标签加减一个数,或形如 [PC, #number] 的表达式。
3.3.7条件执行
多数数据处理指令可以选择根据运算结果更新应用状态寄存器(APSR)中的条件标志。有些指令更新全部标志,有些只更新一部分;未更新的标志保持原值。各条指令影响哪些标志,见其说明。
可以根据其他指令设置的条件标志有条件地执行某条指令,时机可以是:
- 紧接在更新标志的指令之后;
- 在任意多条未更新标志的指令之后。
条件执行可通过条件分支,也可通过给指令加条件码后缀实现。条件码后缀使处理器能根据标志测试条件。若条件指令的条件测试失败,该指令:
- 不执行;
- 不向目的寄存器写入任何值;
- 不影响任何标志;
- 不产生任何异常。
除条件分支以外,条件指令必须位于一个 If-then 指令块内。关于 IT 指令的更多信息与限制,见第 94 页的 IT。视厂商而定,若你把条件指令写在 IT 块之外,汇编器可能自动插入一条 IT 指令。
可用 CBZ 与 CBNZ 指令把寄存器中的值与零比较,并根据结果分支。
条件标志
APSR 包含以下条件标志:
- N:运算结果为负时置 1,否则清 0;
- Z:运算结果为零时置 1,否则清 0;
- C:运算产生进位时置 1,否则清 0;
- V:运算产生溢出时置 1,否则清 0。
发生进位的情形:
- 加法结果大于或等于 232;
- 减法结果为正或零;
- 传送或逻辑指令中内联桶形移位器运算的结果。
加法、减法或比较的结果大于或等于 231、或小于 −231 时发生溢出。
多数指令只有在指定 S 后缀时才更新状态标志,详见各条指令说明。
条件码后缀
可以条件执行的指令带有可选条件码,在语法描述中记作 {cond}。条件执行需要前置的 IT 指令。带条件码的指令只有在 APSR 中的条件标志满足指定条件时才执行。表 23 给出可用的条件码,以及条件码后缀与 N、Z、C、V 标志的关系。
| 后缀 | 标志条件 | 含义 |
|---|---|---|
| EQ | Z = 1 | 相等 |
| NE | Z = 0 | 不相等 |
| CS 或 HS | C = 1 | 高于或等于(无符号 ≥) |
| CC 或 LO | C = 0 | 低于(无符号 <) |
| MI | N = 1 | 负 |
| PL | N = 0 | 正或零 |
| VS | V = 1 | 溢出 |
| VC | V = 0 | 未溢出 |
| HI | C = 1 且 Z = 0 | 高于(无符号 >) |
| LS | C = 0 或 Z = 1 | 低于或等于(无符号 ≤) |
| GE | N = V | 大于或等于(有符号 ≥) |
| LT | N != V | 小于(有符号 <) |
| GT | Z = 0 且 N = V | 大于(有符号 >) |
| LE | Z = 1 或 N != V | 小于或等于(有符号 ≤) |
| AL | 可取任意值 | 总是执行。未指定后缀时即为默认。 |
例 1:求绝对值。该例用条件指令求一个数的绝对值,R0 = ABS(R1)。
MOVS R0, R1 ; R0 = R1,并更新标志 IT MI ; 为“负”条件准备的 IT 指令 RSBMI R0, R1, #0 ; 若为负,则 R0 = -R1
例 2:比较并更新数值。该例用条件指令,在有符号值 R0、R2 分别大于 R1、R3 时更新 R4。
CMP R0, R1 ; 比较 R0 与 R1,设置标志 ITT GT ; 为两个 GT 条件准备的 IT 指令 CMPGT R2, R3 ; 若“大于”,比较 R2 与 R3,设置标志 MOVGT R4, R5 ; 若仍“大于”,执行 R4 = R5
3.3.8指令宽度选择
许多指令根据操作数与目的寄存器的不同,可能生成 16 位编码,也可能生成 32 位编码。对其中部分指令,可用指令宽度后缀强制指定指令长度:.W 后缀强制使用 32 位编码,.N 后缀强制使用 16 位编码。
若指定了指令宽度后缀而汇编器无法生成所要求宽度的编码,汇编器会报错。
某些情况下必须使用 .W 后缀,例如操作数是某条指令或字面数据的标签时(如分支指令)。这是因为汇编器可能无法自动生成正确大小的编码。
使用指令宽度后缀时,把它紧跟在指令助记符之后、条件码(若有)之后。
BCS.W label ; 即使是很短的分支,也生成 32 位指令 ADDS.W R0, R0, R1 ; 虽然同一运算可用 16 位指令完成,仍生成 32 位指令
3.4存储器访问指令
表 24 列出存储器访问类指令。
| 助记符 | 简要说明 | 详见 |
|---|---|---|
| ADR | 装载 PC 相对地址 | 3.4.1 |
| CLREX | 清除独占标记 | 3.4.9 |
| LDM{mode} | 多寄存器装载 | 3.4.6 |
| LDR{type} | 立即数偏移装载寄存器 | 3.4.2 |
| LDR{type} | 寄存器偏移装载寄存器 | 3.4.3 |
| LDR{type}T | 非特权访问装载寄存器 | 3.4.4 |
| LDR | PC 相对地址装载寄存器 | 3.4.5 |
| LDREX{type} | 独占装载寄存器 | 3.4.8 |
| POP | 从堆栈弹出寄存器 | 3.4.7 |
| PUSH | 把寄存器压入堆栈 | 3.4.7 |
| STM{mode} | 多寄存器存储 | 3.4.6 |
| STR{type} | 立即数偏移存储寄存器 | 3.4.2 |
| STR{type} | 寄存器偏移存储寄存器 | 3.4.3 |
| STR{type}T | 非特权访问存储寄存器 | 3.4.4 |
| STREX{type} | 独占存储寄存器 | 3.4.8 |
3.4.1ADR
装载 PC 相对地址。
- 操作数
cond可选条件码;Rd目的寄存器;labelPC 相对表达式。- 操作
- ADR 通过把立即数加到 PC 上来确定地址,并把结果写入目的寄存器。由于地址是 PC 相对的,ADR 产生位置无关代码。若用 ADR 为 BX 或 BLX 生成目标地址,必须确保生成地址的 bit[0] 为 1 才能正确执行。label 相对 PC 的取值必须在 −4095~4095 范围内。
- 限制
- Rd 不能是 SP,也不能是 PC。
- 条件标志
- 本指令不改变标志。
- 示例
ADR R1, TextMessage ; 把标号 TextMessage 处的地址写入 R1
要获得最大偏移范围,或生成非字对齐的地址,可能需要使用 .W 后缀(见 3.3.8 节)。
3.4.2LDR 和 STR,立即数偏移
带立即数偏移、前索引立即数偏移或后索引立即数偏移的装载与存储。
op{type}{cond} Rt, [Rn {, #offset}] ; 立即数偏移
op{type}{cond} Rt, [Rn, #offset]! ; 前索引
op{type}{cond} Rt, [Rn], #offset ; 后索引
opD{cond} Rt, Rt2, [Rn {, #offset}] ; 立即数偏移,两个字
opD{cond} Rt, Rt2, [Rn, #offset]! ; 前索引,两个字
opD{cond} Rt, Rt2, [Rn], #offset ; 后索引,两个字
- 操作数
op为 LDR 或 STR;type:B 无符号字节(装载时零扩展到 32 位)、SB 有符号字节(仅 LDR)、H 无符号半字(装载时零扩展)、SH 有符号半字(仅 LDR),省略表示字;Rt装载/存储的寄存器;Rn作为存储器地址基址的寄存器;offset相对 Rn 的偏移,省略时地址即 Rn 的内容;Rt2双字操作的第二个寄存器。- 操作
- LDR 从存储器装载一个字或两个字到寄存器;STR 把一个或两个寄存器的值存入存储器。带立即数偏移的装载/存储指令支持三种寻址方式:
- 偏移寻址:偏移值与 Rn 得到的地址相加或相减,结果作为存储器访问地址,Rn 不变。语法
[Rn, #offset]。 - 前索引寻址:偏移值与 Rn 得到的地址相加或相减,结果作为访问地址并写回 Rn。语法
[Rn, #offset]!。 - 后索引寻址:以 Rn 得到的地址作为访问地址;偏移值与该地址相加或相减后写回 Rn。语法
[Rn], #offset。
装载或存储的值可以是字节、半字、字或两个字。字节与半字可以是有符号或无符号(见 3.3.5 节“地址对齐”)。表 25 给出立即数、前索引与后索引形式的偏移范围。
| 指令类型 | 立即数偏移 | 前索引 | 后索引 |
|---|---|---|---|
| 字、半字、有符号半字、字节、有符号字节 | −255 ~ 4095 | −255 ~ 255 | −255 ~ 255 |
| 两个字 | −1020 ~ 1020 内 的 4 的倍数 | −1020 ~ 1020 内 的 4 的倍数 | −1020 ~ 1020 内 的 4 的倍数 |
- 限制
-
装载指令:Rt 仅在字装载时可为 SP 或 PC;双字装载时 Rt 必须不同于 Rt2;前索引或后索引形式中 Rn 必须不同于 Rt 与 Rt2。
当 Rt 为 PC 的字装载指令:装入值的 bit[0] 必须为 1 才能正确执行;分支跳转到把该装入值的 bit[0] 清 0 后形成的地址;若指令为条件指令,它必须是 IT 块中的最后一条指令。
存储指令:Rt 仅在字存储时可为 SP;Rt 不能是 PC;Rn 不能是 PC;前索引或后索引形式中 Rn 必须不同于 Rt 与 Rt2。
- 条件标志
- 这些指令不改变标志。
- 示例
LDR R8, [R10] ; 从 R10 中的地址装载到 R8 LDRNE R2, [R5, #960]! ; 条件执行:从 R5 地址上方 960 字节处 ; 装载字到 R2,并把 R5 加 960 STR R2, [R9, #const-struc] ; const-struc 为 0~4095 的常数表达式 STRH R3, [R4], #4 ; 把 R3 作为半字存入 R4 的地址, ; 然后把 R4 加 4 LDRD R8, R9, [R3, #0x20] ; 从 R3 上方 32 字节处装载到 R8, ; 从 R3 上方 36 字节处装载到 R9 STRD R0, R1, [R8], #-16 ; 把 R0 存入 R8 的地址,R1 存入其上 4 字节, ; 然后把 R8 减 16
3.4.3LDR 和 STR,寄存器偏移
带寄存器偏移的装载与存储。
- 操作数
op为 LDR 或 STR;type同 3.4.2 节;Rt装载或存储的寄存器;Rn地址基址寄存器;Rm保存偏移值的寄存器;LSL #n可选移位,n 取 0~3。- 操作
- LDR 从存储器装载寄存器,STR 把寄存器值存入存储器。访问地址是 Rn 加偏移,偏移由 Rm 给出,并可用 LSL 左移最多 3 位。装载或存储的值可以是字节、半字或字;对装载指令,字节与半字可为有符号或无符号。
- 限制
- Rn 不能是 PC;Rm 既不能是 SP 也不能是 PC;Rt 仅在字装载与字存储时可为 SP;Rt 仅在字装载时可为 PC。当 Rt 为 PC 的字装载指令:装入值的 bit[0] 必须为 1 才能正确执行,分支跳转到该半字对齐地址;若指令为条件指令,它必须是 IT 块中的最后一条指令。
- 条件标志
- 这些指令不改变标志。
- 示例
STR R0, [R5, R1] ; 把 R0 存入 R5+R1 的地址 LDRSB R0, [R5, R1, LSL #1] ; 从 R5 + 2×R1 的地址读字节, ; 符号扩展为字值放入 R0 STR R0, [R1, R2, LSL #2] ; 把 R0 存入 R1 + 4×R2 的地址
3.4.4LDR 和 STR,非特权访问
带非特权访问的装载与存储。
- 操作数
offset相对 Rn 的偏移,可取 0~255;省略时地址即 Rn 的值。- 操作
- 这类指令的功能与带立即数偏移的存储器访问指令相同(见 3.4.2 节),区别在于即使运行于特权软件中,它们也只进行非特权访问。在非特权软件中使用时,其行为与普通的带立即数偏移存储器访问指令完全一致。
- 限制
- Rn 不能是 PC;Rt 既不能是 SP 也不能是 PC。
- 条件标志
- 这些指令不改变标志。
- 示例
STRBTEQ R4, [R7] ; 条件执行:把 R4 的最低字节以非特权访问 ; 存入 R7 的地址 LDRHT R2, [R2, #8] ; 以非特权访问从 R2 + 8 的地址装载半字到 R2
3.4.5LDR,PC 相对
从存储器装载寄存器。
LDR{type}{cond} Rt, label
LDRD{cond} Rt, Rt2, label ; 装载两个字
- 操作
- LDR 从 PC 相对的存储器地址装载寄存器,地址由标号或相对 PC 的偏移给出。装载的值可以是字节、半字或字;字节与半字可为有符号或无符号。label 必须位于当前指令的有限范围内,表 26 给出 label 与 PC 之间可能的偏移。
- 限制
- Rt 仅在字装载时可为 SP 或 PC;Rt2 既不能是 SP 也不能是 PC;Rt 必须不同于 Rt2。Rt 为 PC 的字装载指令:装入值的 bit[0] 必须为 1,分支跳转到该半字对齐地址;条件指令必须是 IT 块中最后一条指令。
- 条件标志
- 这些指令不改变标志。
- 示例
LDR R0, LookUpTable ; 从标号 LookUpTable 处装载一个字到 R0 LDRSB R7, localdata ; 从标号 localdata 处读字节,符号扩展为字值放入 R7
要获得最大偏移范围,可能需要使用 .W 后缀(见 3.3.8 节)。
| 指令类型 | 偏移范围 |
|---|---|
| 字、半字、有符号半字、字节、有符号字节 | −4095 ~ 4095 |
| 两个字 | −1020 ~ 1020 |
3.4.6LDM 和 STM
多寄存器装载与存储。
- 操作数
op为 LDM 或 STM;addr_mode:IA 每次访问后地址递增(默认),DB 每次访问前地址递减;!可选回写后缀,存在时把最后一次访问的地址写回 Rn;reglist一个或多个寄存器的列表,用大括号包围,可含寄存器范围,多于一个寄存器或范围时用逗号分隔。- 同义名
- LDM 与 LDMFD 是 LDMIA 的同义词,LDMFD 指其用于从满递减堆栈弹出数据;LDMEA 是 LDMDB 的同义词,指其用于从空递增堆栈弹出数据;STM 与 STMEA 是 STMIA 的同义词,STMEA 指其用于把数据压入空递增堆栈;STMFD 是 STMDB 的同义词,指其用于把数据压入满递减堆栈。
- 操作
- LDM 从基于 Rn 的存储器地址把字值装载到 reglist 中的寄存器;STM 把 reglist 中寄存器的字值存储到基于 Rn 的存储器地址。
- 对 LDM、LDMIA、LDMFD、STM、STMIA、STMEA,访问地址为 Rn 到 Rn + 4×(n−1) 之间 4 字节间隔的地址,n 为 reglist 中寄存器个数。访问按寄存器序号递增顺序进行,序号最小的寄存器使用最低地址,序号最大的使用最高地址。指定回写后缀时,Rn + 4×(n−1) 写回 Rn。
- 对 LDMDB、LDMEA、STMDB、STMFD,访问地址为 Rn 到 Rn − 4×(n−1) 之间 4 字节间隔的地址。访问按寄存器序号递减顺序进行,序号最大的寄存器使用最高地址,序号最小的使用最低地址。指定回写后缀时,Rn − 4×(n−1) 写回 Rn。
PUSH 与 POP 指令可以写成这种形式(详见 3.4.7 节)。
- 限制
- Rn 不能是 PC;reglist 不能含 SP;任何 STM 指令的 reglist 不能含 PC;任何 LDM 指令中,若 reglist 含 LR 则不能含 PC;指定回写后缀时 reglist 不能含 Rn。当 LDM 的 reglist 含 PC 时:装入 PC 的值的 bit[0] 必须为 1 才能正确执行,分支跳转到该半字对齐地址;条件指令必须是 IT 块中最后一条指令。
- 条件标志
- 这些指令不改变标志。
- 示例
LDM R8, {R0,R2,R9} ; LDMIA 是 LDM 的同义词 STMDB R1!, {R3-R6,R11,R12}错误示例:
STM R5!, {R5,R4,R9}(为 R5 存储的值不可预测);LDM R2, {}(列表中至少需要一个寄存器)。
3.4.7PUSH 和 POP
把寄存器压入满递减堆栈,以及从满递减堆栈弹出寄存器。
PUSH{cond} reglist
POP{cond} reglist
- 操作数
reglist非空的寄存器列表,用大括号包围,可含寄存器范围,多于一个寄存器或范围时用逗号分隔。- 操作
- PUSH 与 POP 分别是基于 SP 的 STMDB 与 LDM(或 LDMIA)的同义写法,且把最终访问地址写回 SP;在这些场合应优先使用 PUSH 与 POP 助记符。PUSH 按寄存器序号递减顺序把寄存器存入堆栈,序号最大的使用最高地址;POP 按序号递增顺序从堆栈装载寄存器,序号最小的使用最低地址。详见 3.4.6 节。
- 限制
- reglist 不能含 SP;对 PUSH,reglist 不能含 PC;对 POP,若 reglist 含 LR 则不能含 PC。当 POP 的 reglist 含 PC 时:装入 PC 的值的 bit[0] 必须为 1,分支跳转到该半字对齐地址;条件指令必须是 IT 块中最后一条指令。
- 条件标志
- 这些指令不改变标志。
- 示例
PUSH {R0,R4-R7} PUSH {R2,LR} POP {R0,R10,PC}
3.4.8LDREX 和 STREX
独占装载与独占存储。
LDREX{cond} Rt, [Rn {, #offset}]
STREX{cond} Rd, Rt, [Rn {, #offset}]
LDREXB{cond} Rt, [Rn]
STREXB{cond} Rd, Rt, [Rn]
LDREXH{cond} Rt, [Rn]
STREXH{cond} Rd, Rt, [Rn]
- 操作数
Rd返回状态的目的寄存器;Rt装载或存储的寄存器;offset可选的偏移,省略时地址即 Rn 的值。- 操作
- LDREX、LDREXB、LDREXH 分别从存储器地址装载字、字节、半字。STREX、STREXB、STREXH 分别尝试把字、字节、半字存入存储器地址。任何独占存储指令使用的地址,必须与最近执行的独占装载指令的地址相同;其存储的数据宽度也必须与前一独占装载指令装载的宽度相同。也就是说,软件必须始终用一条独占装载指令与一条匹配的独占存储指令来完成同步操作(见第 2.7 节“同步原语”)。若独占存储指令执行了存储,它向目的寄存器写 0;若没有执行存储,则写 1。写 0 时可保证在独占装载与独占存储之间,系统中没有其他进程访问过该存储器单元。为提高性能,应使独占装载与对应的独占存储之间的指令数尽量少。
- 限制
- 不能使用 PC;Rd 与 Rt 不能使用 SP;对 STREX,Rd 必须不同于 Rt 与 Rn;offset 必须是 0~1020 范围内 4 的倍数。
- 条件标志
- 这些指令不改变标志。
- 示例
MOV R1, #0x1 ; 初始化“锁已被取走”的值 try LDREX R0, [LockAddr] ; 读取锁值 CMP R0, #0 ; 锁是否空闲? ITTEQ ; 为 STREXEQ 与 CMPEQ 准备 IT STREXEQ R0, R1, [LockAddr] ; 尝试取锁 CMPEQ R0, #0 ; 是否成功? BNE try ; 否 —— 重试 ; 是 —— 已取得锁
对与前一独占装载指令不同的地址执行独占存储,结果不可预测。
3.4.9CLREX
清除独占标记。
- 操作
- CLREX 使下一条 STREX、STREXB 或 STREXH 指令向目的寄存器写 1、且不执行存储。它在异常处理程序中很有用:若同步操作在独占装载与匹配的独占存储之间发生异常,可强制使独占存储失败。
- 条件标志
- 本指令不改变标志。
- 示例
CLREX
3.5通用数据处理指令
表 27 列出数据处理指令。
| 助记符 | 简要说明 | 详见 |
|---|---|---|
| ADC | 带进位加法 | 3.5.1 |
| ADD | 加法 | 3.5.1 |
| ADDW | 加法 | 3.5.1 |
| AND | 逻辑与 | 3.5.2 |
| ASR | 算术右移 | 3.5.3 |
| BIC | 位清除 | 3.5.2 |
| CLZ | 前导零计数 | 3.5.4 |
| CMN | 比较取负 | 3.5.5 |
| CMP | 比较 | 3.5.5 |
| EOR | 异或 | 3.5.2 |
| LSL | 逻辑左移 | 3.5.3 |
| LSR | 逻辑右移 | 3.5.3 |
| MOV | 传送 | 3.5.6 |
| MOVT | 传送高半字 | 3.5.7 |
| MOVW | 传送 16 位常数 | 3.5.6 |
| MVN | 传送取反 | 3.5.6 |
| ORN | 逻辑或非 | 3.5.2 |
| ORR | 逻辑或 | 3.5.2 |
| RBIT | 位序反转 | 3.5.8 |
| REV | 反转字内字节序 | 3.5.8 |
| REV16 | 反转每个半字内字节序 | 3.5.8 |
| REVSH | 反转低半字字节序并符号扩展 | 3.5.8 |
| ROR | 循环右移 | 3.5.3 |
| RRX | 带扩展的循环右移 | 3.5.3 |
| RSB | 反向减法 | 3.5.1 |
| SBC | 带借位减法 | 3.5.1 |
| SUB | 减法 | 3.5.1 |
| SUBW | 减法 | 3.5.1 |
| TEQ | 等价测试 | 3.5.9 |
| TST | 位测试 | 3.5.9 |
3.5.1ADD、ADC、SUB、SBC 和 RSB
加法、带进位加法、减法、带借位减法与反向减法。
op{S}{cond} {Rd,} Rn, Operand2
op{cond} {Rd,} Rn, #imm12 ; 仅 ADD 与 SUB
- 操作
- ADD 把 operand2 或 imm12 的值加到 Rn 的值上;ADC 把 Rn 与 operand2 之值再加上进位标志;SUB 从 Rn 的值中减去 operand2 或 imm12 的值;SBC 从 Rn 的值中减去 operand2,若进位标志为 0 则结果再减 1;RSB 从 operand2 的值中减去 Rn 的值,由于 operand2 选项范围宽,这很有用。用 ADC 与 SBC 可以合成多字算术运算。ADDW 等效于使用 imm12 操作数的 ADD 语法,SUBW 等效于使用 imm12 操作数的 SUB 语法。
- 限制
-
operand2 既不能是 SP 也不能是 PC。
Rd 仅在 ADD 与 SUB 中可为 SP,且还须满足:Rn 也是 SP;operand2 中的移位若存在,须限于最多 3 位的 LSL。
Rn 仅在 ADD 与 SUB 中可为 SP。
Rd 仅在
ADD{cond} PC, PC, Rm指令中可为 PC,此时:不得指定 S 后缀;Rm 既不能是 PC 也不能是 SP;条件指令必须是 IT 块中最后一条指令。除
ADD{cond} PC, PC, Rm外,Rn 仅在 ADD 与 SUB 中可为 PC,且还须满足:不得指定 S 后缀;第二操作数必须是 0~4095 范围内的常数。 - 条件标志
- 若指定 S,这些指令根据结果更新 N、Z、C、V 标志。
- 示例
ADD R2, R1, R3 SUBS R8, R6, #240 ; 根据结果设置标志 RSB R4, R4, #1280 ; 用 1280 减去 R4 的内容 ADCHI R11, R0, R3 ; 仅当 C=1 且 Z=0 时执行
用 PC 做加减法时,PC 的 bit[1:0] 在执行运算前会取整为 b00,使计算的基地址字对齐。若要生成某条指令的地址,需根据 PC 值调整常数;Arm 建议改用 ADR 指令,因为汇编器会自动算出正确的常数。
多字算术示例:64 位加法。把 R2、R3 中的 64 位整数加到 R0、R1 中的 64 位整数,结果放在 R4、R5。
ADDS R4, R0, R2 ; 最低有效字相加 ADC R5, R1, R3 ; 最高有效字带进位相加
多字算术示例:96 位减法。从 R6、R2、R8 中的 96 位整数减去 R9、R1、R11 中的整数,结果存入 R6、R9、R2。多字值不必使用连续寄存器。
SUBS R6, R6, R9 ; 最低有效字相减 SBCS R9, R2, R1 ; 中间字带借位相减 SBC R2, R8, R11 ; 最高有效字带借位相减
3.5.2AND、ORR、EOR、BIC 和 ORN
逻辑与、或、异或、位清除与或非。
- 操作
- AND、EOR、ORR 对 Rn 与 operand2 的值执行按位与、异或、或运算;BIC 把 Rn 的位与 operand2 对应位的反码做与运算;ORN 把 Rn 的位与 operand2 对应位的反码做或运算。
- 限制
- 不能使用 SP 或 PC。
- 条件标志
- 若指定 S:根据结果更新 N、Z 标志;在计算 operand2 过程中可能更新 C 标志;不影响 V 标志。
- 示例
AND R9, R2, #0xFF00 ORREQ R2, R0, R5 ANDS R9, R8, #0x19 EORS R7, R11, #0x18181818 BIC R0, R1, #0xab ORN R7, R11, R14, ROR #4 ORNS R7, R11, R14, ASR #32
3.5.3ASR、LSL、LSR、ROR 和 RRX
算术右移、逻辑左移、逻辑右移、循环右移与带扩展的循环右移。
op{S}{cond} Rd, Rm, Rs
op{S}{cond} Rd, Rm, #n
RRX{S}{cond} Rd, Rm
- 操作数
Rs保存施加于 Rm 的移位长度,只使用最低字节,范围 0~255;n移位长度,范围随指令不同:ASR 1~32,LSL 0~31,LSR 1~32,ROR 1~31。- 操作
- ASR、LSL、LSR、ROR 按常数 n 或寄存器 Rs 给出的位数把 Rm 中的位左移或右移;RRX 把 Rm 中的位右移 1 位。所有这些指令都把结果写入 Rd,而 Rm 的值保持不变。各种移位产生的具体结果见 3.3.4 节“移位操作”。
- 限制
- 不能使用 SP 或 PC。
- 条件标志
- 若指定 S:根据结果更新 N、Z 标志;C 标志更新为最后移出的位,移位长度为 0 时除外。
- 示例
ASR R7, R8, #9 ; 算术右移 9 位 LSLS R1, R2, #3 ; 逻辑左移 3 位并更新标志 LSR R4, R5, #6 ; 逻辑右移 6 位 ROR R4, R5, R6 ; 按 R6 最低字节的值循环右移 RRX R4, R5 ; 带扩展的循环右移
MOV{S}{cond} Rd, Rm 是 LSL{S}{cond} Rd, Rm, #0 的首选写法。
3.5.4CLZ
前导零计数。
- 操作
- CLZ 统计 Rm 值中前导零的个数,结果返回 Rd。若源寄存器未置位任何位,结果为 32;若 bit[31] 已置位,结果为 0。
- 限制
- 不能使用 SP 或 PC。
- 条件标志
- 本指令不改变标志。
- 示例
CLZ R4, R9 CLZNE R2, R3
3.5.5CMP 和 CMN
比较与比较取负。
CMP{cond} Rn, Operand2
CMN{cond} Rn, Operand2
- 操作
- 这些指令把寄存器中的值与 operand2 比较,根据结果更新条件标志,但不把结果写入寄存器。CMP 从 Rn 的值中减去 operand2 的值,等同于 SUBS 指令,只是丢弃结果;CMN 把 operand2 的值加到 Rn 的值上,等同于 ADDS 指令,只是丢弃结果。
- 限制
- 不能使用 PC;operand2 不能是 SP。
- 条件标志
- 这些指令根据结果更新 N、Z、C、V 标志。
- 示例
CMP R2, R9 CMN R0, #6400 CMPGT SP, R7, LSL #2
3.5.6MOV 和 MVN
传送与传送取反。
MOV{S}{cond} Rd, Operand2
MOV{cond} Rd, #imm16
MVN{S}{cond} Rd, Operand2
- 操作数
imm160~65535 范围内的任意值。- 操作
- MOV 把 operand2 的值复制到 Rd。当 MOV 的 operand2 是带 LSL #0 之外移位的寄存器时,首选写法是对应的移位指令:ASR、LSL(n≠0)、LSR、ROR、RRX。此外 MOV 还允许把一些操作数形式作为移位指令的同义写法,例如
MOV{S}{cond} Rd, Rm, LSL Rs等同于LSL{S}{cond} Rd, Rm, Rs。MVN 取 operand2 的值,按位逻辑取反后放入 Rd。 - 限制
- SP 与 PC 仅可用于 MOV 指令,且还须满足:第二操作数必须是不带移位的寄存器;不得指定 S 后缀。对写往 PC 的值,其 bit[0] 被忽略,分支跳转到把该值的 bit[0] 强制为 0 后形成的地址。
- 条件标志
- 若指定 S:根据结果更新 N、Z 标志;在计算 operand2 过程中可能更新 C 标志;不影响 V 标志。
- 示例
MOVS R11, #0x000B ; 把 0x000B 写入 R11,标志被更新 MOV R1, #0xFA05 ; 把 0xFA05 写入 R1,标志不更新 MOVS R10, R12 ; 把 R12 的值写入 R10,标志被更新 MOV R3, #23 ; 把 23 写入 R3 MOV R8, SP ; 把堆栈指针的值写入 R8 MVNS R2, #0xF ; 把 0xFFFFFFF0(0xF 的按位取反)写入 R2 并更新标志
虽然可用 MOV 作为分支指令,Arm 强烈建议使用 BX 或 BLX 分支,以便软件可移植到 Arm 指令集。MOVW 指令提供与 MOV 相同的功能,但只限于使用 imm16 操作数。
3.5.7MOVT
传送高半字。
- 操作
- MOVT 把 16 位立即数 imm16 写入目的寄存器的高半字 Rd[31:16],不影响 Rd[15:0]。MOV 与 MOVT 指令对配合使用,可以生成任意 32 位常数。
- 限制
- Rd 既不能是 SP 也不能是 PC。
- 条件标志
- 本指令不改变标志。
- 示例
MOVT R3, #0xF123 ; 把 0xF123 写入 R3 的高半字, ; 低半字与 APSR 不变
3.5.8REV、REV16、REVSH 和 RBIT
反转字节序与反转位序。
- 操作数
op为:REV(反转一个字内的字节序)、REV16(独立反转每个半字内的字节序)、REVSH(反转低半字内的字节序并符号扩展到 32 位)、RBIT(反转 32 位字内的位序)。- 操作
- 用这些指令改变数据的字节序(端序):REV 把 32 位大端数据转成小端数据,或反之;REV16 把 16 位大端数据转成小端数据,或反之;REVSH 把 16 位有符号大端数据转成 32 位有符号小端数据,或反之。
- 限制
- 不能使用 SP 或 PC。
- 条件标志
- 这些指令不改变标志。
- 示例
REV R3, R7 ; 反转 R7 中值的字节序,结果写入 R3 REV16 R0, R0 ; 反转 R0 中每个 16 位半字的字节序 REVSH R0, R5 ; 反转低半字节序并符号扩展 REVHS R3, R7 ; 带 HS 条件执行的反转 RBIT R7, R8 ; 反转 R8 中值的位序,结果写入 R7
3.5.9TST 和 TEQ
位测试与等价测试。
TST{cond} Rn, Operand2
TEQ{cond} Rn, Operand2
- 操作
- 这些指令把寄存器中的值与 operand2 比较,根据结果更新条件标志,但不把结果写入寄存器。TST 对 Rn 的值与 operand2 做按位与运算,等同于 ANDS 指令,只是丢弃结果。要测试 Rn 的某一位是 0 还是 1,可使用 TST 指令,operand2 常数把该位置 1、其余位清 0。TEQ 对 Rn 的值与 operand2 做按位异或运算,等同于 EORS 指令,只是丢弃结果。用 TEQ 可以在不影响 V、C 标志的情况下测试两个值是否相等;TEQ 也适合测试某个值的符号,比较之后 N 标志就是两个操作数符号位的逻辑异或。
- 限制
- 不能使用 SP 或 PC。
- 条件标志
- 这些指令根据结果更新 N、Z 标志;在计算 operand2 过程中可能更新 C 标志;不影响 V 标志。
- 示例
TST R0, #0x3F8 ; 把 R0 的值与 0x3F8 按位与, ; APSR 被更新,结果被丢弃 TEQEQ R10, R9 ; 条件测试 R10 是否等于 R9, ; APSR 被更新,结果被丢弃
3.6乘法与除法指令
表 28 列出乘法与除法指令。
| 助记符 | 简要说明 | 详见 |
|---|---|---|
| MLA | 乘加,32 位结果 | 3.6.1 |
| MLS | 乘减,32 位结果 | 3.6.1 |
| MUL | 乘法,32 位结果 | 3.6.1 |
| SDIV | 有符号除法 | 3.6.3 |
| SMLAL | 有符号长乘加(32×32+64),64 位结果 | 3.6.2 |
| SMULL | 有符号长乘(32×32),64 位结果 | 3.6.2 |
| UDIV | 无符号除法 | 3.6.3 |
| UMLAL | 无符号长乘加(32×32+64),64 位结果 | 3.6.2 |
| UMULL | 无符号长乘(32×32),64 位结果 | 3.6.2 |
3.6.1MUL、MLA 和 MLS
使用 32 位操作数的乘法、乘加与乘减,产生 32 位结果。
MUL{S}{cond} {Rd,} Rn, Rm ; 乘法
MLA{cond} Rd, Rn, Rm, Ra ; 乘加
MLS{cond} Rd, Rn, Rm, Ra ; 乘减
- 操作数
Rd目的寄存器,省略时目的寄存器为 Rn;Rn、Rm保存待相乘值的寄存器;Ra保存被加或被减值的寄存器。- 操作
- MUL 把 Rn 与 Rm 的值相乘,结果的最低 32 位放入 Rd;MLA 把 Rn 与 Rm 相乘,加上 Ra 的值,结果的最低 32 位放入 Rd;MLS 把 Rn 与 Rm 相乘,用 Ra 的值减去乘积,结果的最低 32 位放入 Rd。这些指令的结果与操作数是否有符号无关。
- 限制
- 不能使用 SP 与 PC。若对 MUL 使用 S 后缀:Rd、Rn、Rm 都必须位于 R0~R7;Rd 必须与 Rm 相同;不得使用 cond 后缀。
- 条件标志
- 若指定 S,MUL 根据结果更新 N、Z 标志,不影响 C、V 标志。
- 示例
MUL R10, R2, R5 ; 乘法,R10 = R2 × R5 MLA R10, R2, R1, R5 ; 乘加,R10 = (R2 × R1) + R5 MULS R0, R2, R2 ; 乘法并更新标志,R0 = R2 × R2 MULLT R2, R3, R2 ; 条件乘法,R2 = R3 × R2 MLS R4, R5, R6, R7 ; 乘减,R4 = R7 − (R5 × R6)
3.6.2UMULL、UMLAL、SMULL 和 SMLAL
使用 32 位操作数的有符号与无符号长乘,可选累加,产生 64 位结果。
- 操作数
op为:UMULL 无符号长乘、UMLAL 无符号长乘加、SMULL 有符号长乘、SMLAL 有符号长乘加;RdHi, RdLo目的寄存器,对 UMLAL 与 SMLAL 它们还保存累加值。- 操作
- UMULL 把 Rn、Rm 的值解释为无符号整数相乘,结果最低 32 位放 RdLo、最高 32 位放 RdHi。UMLAL 把两者用无符号整数相乘,把 64 位结果加到 RdHi、RdLo 中的 64 位无符号整数上,结果写回 RdHi、RdLo。SMULL 把 Rn、Rm 的值解释为二进制补码有符号整数相乘,结果最低 32 位放 RdLo、最高 32 位放 RdHi。SMLAL 把两者用有符号整数相乘,把 64 位结果加到 RdHi、RdLo 中的 64 位有符号整数上,结果写回 RdHi、RdLo。
- 限制
- 不能使用 SP 或 PC;RdHi 与 RdLo 必须是不同的寄存器。
- 条件标志
- 这些指令不影响条件标志。
- 示例
UMULL R0, R4, R5, R6 ; 无符号 (R4,R0) = R5 × R6 SMLAL R4, R5, R3, R8 ; 有符号 (R5,R4) = (R5,R4) + R3 × R8
3.6.3SDIV 和 UDIV
有符号除法与无符号除法。
SDIV{cond} {Rd,} Rn, Rm
UDIV{cond} {Rd,} Rn, Rm
- 操作
- SDIV 用 Rm 的值对 Rn 的值做有符号整数除法;UDIV 做无符号整数除法。对两条指令,若 Rn 的值不能被 Rm 的值整除,结果向零方向取整。
- 限制
- 不能使用 SP 或 PC。
- 条件标志
- 这些指令不改变标志。
- 示例
SDIV R0, R2, R4 ; 有符号除法,R0 = R2 / R4 UDIV R8, R8, R1 ; 无符号除法,R8 = R8 / R1
3.7饱和指令
本节介绍饱和指令 SSAT 与 USAT。
3.7.1SSAT 和 USAT
饱和到任意位位置的有符号与无符号饱和,可在饱和前选择移位。
- 操作数
op为:SSAT 把有符号值饱和到有符号范围、USAT 把有符号值饱和到无符号范围;n饱和到的位位置:SSAT 取 1~32,USAT 取 0~31;Rm保存待饱和值的寄存器;shift #s饱和前施加于 Rm 的可选移位,只能是 ASR #s(s 取 1~31)或 LSL #s(s 取 0~31)。- 操作
- 这些指令饱和到有符号或无符号的 n 位值。SSAT 先施加指定移位,再饱和到有符号范围 −2n−1 ≤ x ≤ 2n−1−1;USAT 先施加指定移位,再饱和到无符号范围 0 ≤ x ≤ 2n−1。
对 SSAT 的有符号 n 位饱和:
- 若待饱和值小于 −2n−1,返回 −2n−1;
- 若待饱和值大于 2n−1−1,返回 2n−1−1;
- 否则返回待饱和值本身。
对 USAT 的无符号 n 位饱和:
- 若待饱和值小于 0,返回 0;
- 若待饱和值大于 2n−1,返回 2n−1;
- 否则返回待饱和值本身。
若返回值与待饱和值不同,称为发生了饱和。发生饱和时指令把 APSR 中的 Q 标志置 1,否则 Q 标志保持不变。要把 Q 标志清 0,必须使用 MSR 指令(见 3.9.7 节);要读取 Q 标志状态,使用 MRS 指令(见 3.9.6 节)。
- 限制
- 不能使用 SP 或 PC。
- 条件标志
- 这些指令不影响条件标志;若发生饱和,则把 Q 标志置 1。
- 示例
SSAT R7, #16, R7, LSL #4 ; 把 R7 的值逻辑左移 4 位,再饱和为 ; 有符号 16 位值并写回 R7 USATNE R0, #7, R5 ; 条件地把 R5 的值饱和为无符号 7 位值 ; 并写入 R0
3.8位域、分支与控制指令
表 29 列出对寄存器中相邻的一组位(位域)进行操作的指令。
| 助记符 | 简要说明 | 详见 |
|---|---|---|
| BFC | 位域清零 | 3.8.1 |
| BFI | 位域插入 | 3.8.1 |
| SBFX | 有符号位域提取 | 3.8.2 |
| SXTB | 字节符号扩展 | 3.8.3 |
| SXTH | 半字符号扩展 | 3.8.3 |
| UBFX | 无符号位域提取 | 3.8.2 |
| UXTB | 字节零扩展 | 3.8.3 |
| UXTH | 半字零扩展 | 3.8.3 |
3.8.1BFC 和 BFI
位域清零与位域插入。
BFC{cond} Rd, #lsb, #width
BFI{cond} Rd, Rn, #lsb, #width
- 操作数
lsb位域最低位的位置,必须在 0~31;width位域宽度,必须在 1~32−lsb 范围。- 操作
- BFC 清除寄存器中的一个位域:把 Rd 中从低位 lsb 开始的 width 位清 0,Rd 的其他位不变。BFI 把一个寄存器中的位域复制到另一个寄存器:用 Rn 中从 bit[0] 开始的 width 位,替换 Rd 中从低位 lsb 开始的 width 位,Rd 的其他位不变。
- 限制
- 不能使用 SP 与 PC。
- 条件标志
- 这些指令不影响标志。
- 示例
BFC R4, #8, #12 ; 把 R4 的 bit8~bit19(12 位)清 0 BFI R9, R2, #8, #12 ; 用 R2 的 bit0~bit11 替换 R9 的 bit8~bit19
3.8.2SBFX 和 UBFX
有符号位域提取与无符号位域提取。
SBFX{cond} Rd, Rn, #lsb, #width
UBFX{cond} Rd, Rn, #lsb, #width
- 操作
- SBFX 从一个寄存器中提取位域,符号扩展到 32 位,结果写入目的寄存器;UBFX 提取位域后零扩展到 32 位,结果写入目的寄存器。
- 限制
- 不能使用 SP 与 PC。
- 条件标志
- 这些指令不影响标志。
- 示例
SBFX R0, R1, #20, #4 ; 从 R1 提取 bit20~bit23(4 位),符号扩展到 ; 32 位后写入 R0 UBFX R8, R11, #9, #10 ; 从 R11 提取 bit9~bit18(10 位),零扩展到 ; 32 位后写入 R8
3.8.3SXT 和 UXT
符号扩展与零扩展。
SXTextend{cond} {Rd,} Rm {, ROR #n}
UXTextend{cond} {Rd,} Rm {, ROR #n}
- 操作数
extend为:B 把 8 位值扩展为 32 位,H 把 16 位值扩展为 32 位;ROR #n可为 ROR #8(Rm 的值循环右移 8 位)、ROR #16、ROR #24,省略时不做循环。- 操作
- 指令先按 0、8、16 或 24 位把 Rm 的值循环右移,再从结果中提取位:SXTB 提取 bits[7:0] 并符号扩展到 32 位;UXTB 提取 bits[7:0] 并零扩展到 32 位;SXTH 提取 bits[15:0] 并符号扩展到 32 位;UXTH 提取 bits[15:0] 并零扩展到 32 位。
- 限制
- 不能使用 SP 与 PC。
- 条件标志
- 这些指令不影响标志。
- 示例
SXTH R4, R6, ROR #16 ; R6 循环右移 16 位,取结果的低半字, ; 符号扩展到 32 位后写入 R4 UXTB R3, R10 ; 取 R10 值的最低字节,零扩展后写入 R3
3.8.4B、BL、BX 和 BLX
分支指令。
B{cond} label
BL{cond} label
BX{cond} Rm
BLX{cond} Rm
- 操作数
- B 为(立即数)分支;BL 为带链接的(立即数)分支;BX 为间接(寄存器)分支;BLX 为带链接的间接(寄存器)分支;
label为 PC 相对表达式;Rm为指示分支目标地址的寄存器,其 bit[0] 必须为 1,但实际分支地址是把该位改为 0 后形成的地址。 - 操作
- 所有这些指令都使程序分支到 label 或 Rm 指示的地址。此外:BL 与 BLX 把下一条指令的地址写入 LR(链接寄存器 R14);BX 与 BLX 在 Rm 的 bit[0] 为 0 时产生用法故障异常。
B cond label是唯一既可在 IT 块内、也可在 IT 块外使用的条件指令,其他分支指令在 IT 块内必须带条件、在 IT 块外必须无条件。
表 31 给出各种分支指令的范围。
要获得最大分支范围,可能需要使用 .W 后缀(见 3.3.8 节)。
| 指令 | 分支范围 |
|---|---|
| B label | −16 MB ~ +16 MB |
| Bcond label(IT 块外) | −1 MB ~ +1 MB |
| Bcond label(IT 块内) | −16 MB ~ +16 MB |
| BL{cond} label | −16 MB ~ +16 MB |
| BX{cond} Rm | 寄存器中的任意值 |
| BLX{cond} Rm | 寄存器中的任意值 |
- 限制
- BLX 指令中不能使用 PC;对 BX 与 BLX,Rm 的 bit[0] 必须为 1 才能正确执行,但分支到把 bit[0] 改为 0 后形成的目标地址;这些指令位于 IT 块内时,必须是 IT 块的最后一条指令。
- 条件标志
- 这些指令不改变标志。
- 示例
B loopA ; 分支到 loopA BLE ng ; 条件分支到标号 ng B.W target ; 分支到 16MB 范围内的 target BEQ target ; 条件分支到 target BEQ.W target ; 条件分支到 1MB 范围内的 target BL funC ; 带链接分支(调用)到函数 funC,返回地址存入 LR BX LR ; 从函数调用返回 BXNE R0 ; 条件分支到 R0 中保存的地址 BLX R0 ; 带链接间接分支(调用)到 R0 中保存的地址
Bcond 是唯一不要求在 IT 块内的条件指令,但在 IT 块内时它具有更长的分支范围。
3.8.5CBZ 和 CBNZ
比较为零则分支、比较非零则分支。
CBZ Rn, label CBNZ Rn, label
- 操作
- 用 CBZ 与 CBNZ 可以避免改变条件标志并减少指令数。
CBZ Rn, label不改变条件标志,但等效于CMP Rn, #0加BEQ label;CBNZ Rn, label不改变条件标志,但等效于CMP Rn, #0加BNE label。 - 限制
- Rn 必须在 R0~R7 范围内;分支目标必须位于本指令之后 4~130 字节内;这些指令不得在 IT 块内使用。
- 条件标志
- 这些指令不改变标志。
- 示例
CBZ R5, target ; R5 为零则向前分支 CBNZ R0, target ; R0 非零则向前分支
3.8.6IT
If-Then 条件指令。
- 操作数
x指定 IT 块中第二条指令的条件切换;y指定第三条;z指定第四条;cond指定 IT 块中第一条指令的条件。第二、三、四条指令的条件切换可以是:T(Then,对指令施加条件 cond)、E(Else,对指令施加 cond 的反条件)。- 操作
- IT 指令使它后面的最多四条指令成为条件指令,这些条件可以完全相同,也可以部分为另一些条件的逻辑反。IT 指令后面的条件指令构成 IT 块。IT 块中的指令(包括分支)必须在其语法的 {cond} 部分指定条件。
汇编器可能能够自动为条件指令生成所需的 IT 指令,这样就不必自己编写,详见汇编器文档。IT 块中的 BKPT 指令总是执行,即使其条件不成立。
异常可以发生在 IT 指令与对应 IT 块之间,也可以发生在 IT 块内部。这类异常会进入相应的异常处理程序,并在 LR 与压栈的 PSR 中留下合适的返回信息。为异常返回设计的指令可以照常用于从异常返回,IT 块的执行会正确恢复;这是允许修改 PC 的指令分支到 IT 块内指令的唯一途径。
- 限制
-
以下指令不允许出现在 IT 块内:IT;CBZ 与 CBNZ;CPSID 与 CPSIE。
使用 IT 块的其他限制:分支或任何修改 PC 的指令必须位于 IT 块外,或必须是 IT 块内最后一条指令,包括
ADD PC, PC, Rm、MOV PC, Rm、B/BL/BX/BLX、任何写 PC 的 LDM/LDR/POP 指令、TBB 与 TBH;不得分支到 IT 块内的任何指令,从异常处理程序返回时除外;除 Bcond 外所有条件指令都必须在 IT 块内,Bcond 可在块外或块内,但在块内时分支范围更大;IT 块内每条指令指定的条件码后缀,必须与其他指令相同或为其逻辑反。 - 条件标志
- 本指令不改变标志。
- 示例
ITTE NE ; 接下来的 3 条指令为条件指令 ANDNE R0, R0, R1 ; ANDNE 不更新条件标志 ADDSNE R2, R2, #1 ; ADDSNE 更新条件标志 MOVEQ R2, R3 ; 条件传送 CMP R0, #9 ; 把 R0 的十六进制值(0~15)转成 ASCII ; ('0'-'9'、'A'-'F') ITE GT ; 接下来的 2 条指令为条件指令 ADDGT R1, R0, #55 ; 0xA → 'A' ADDLE R1, R0, #48 ; 0x0 → '0' IT GT ; 只含一条条件指令的 IT 块 ADDGT R1, R1, #1 ; 条件地把 R1 加 1 ITTEE EQ ; 接下来的 4 条指令为条件指令 MOVEQ R0, R1 ; 条件传送 ADDEQ R2, R2, #10 ; 条件加法 ANDNE R3, R3, #1 ; 条件与 BNE.W dloop ; 分支指令只能作为 IT 块的最后一条指令 IT NE ; 下一条指令为条件指令 ADD R0, R0, R1 ; 语法错误:IT 块内未使用条件码
IT 指令中的 cond 可以使用 AL(总是条件)。若如此,IT 块中所有指令都必须是无条件的,且 x、y、z 各自必须是 T 或被省略,不能是 E。
3.8.7TBB 和 TBH
表分支(字节)与表分支(半字)。
TBB [Rn, Rm] TBH [Rn, Rm, LSL #1]
- 操作数
Rn保存分支长度表地址的寄存器;若 Rn 为 PC,表地址就是 TBB 或 TBH 指令之后紧接着的那个字节的地址。Rm索引寄存器,保存表的索引;对半字表,LSL #1 把 Rm 的值加倍,形成正确的表内偏移。- 操作
- 这些指令使用字节偏移表(TBB)或半字偏移表(TBH)进行 PC 相对的向前分支。Rn 提供表的指针,Rm 提供表内索引。对 TBB,分支偏移是表中返回字节值(无符号)的 2 倍;对 TBH,分支偏移是表中返回半字值(无符号)的 2 倍。分支目标为 TBB 或 TBH 指令之后紧接的那个字节地址加上该偏移。
- 限制
- Rn 不能是 SP;Rm 不能是 SP,也不能是 PC;这些指令用在 IT 块内时,必须是 IT 块的最后一条指令。
- 条件标志
- 这些指令不改变标志。
- 示例
ADR.W R0, BranchTable_Byte TBB [R0, R1] ; R1 为索引,R0 为分支表基地址 Case1 ; 指令序列 Case2 ; 指令序列 Case3 ; 指令序列 BranchTable_Byte DCB 0 ; Case1 偏移计算 DCB ((Case2-Case1)/2) ; Case2 偏移计算 DCB ((Case3-Case1)/2) ; Case3 偏移计算 TBH [PC, R1, LSL #1] ; R1 为索引,PC 作为分支表基地址 BranchTable_H DCI ((CaseA - BranchTable_H)/2) ; CaseA 偏移计算 DCI ((CaseB - BranchTable_H)/2) ; CaseB 偏移计算 DCI ((CaseC - BranchTable_H)/2) ; CaseC 偏移计算 CaseA ; 指令序列 CaseB ; 指令序列 CaseC ; 指令序列
3.9其他指令
表 32 列出其余 Cortex-M3 指令。
| 助记符 | 简要说明 | 详见 |
|---|---|---|
| BKPT | 断点 | 3.9.1 |
| CPSID | 改变处理器状态,禁止中断 | 3.9.2 |
| CPSIE | 改变处理器状态,使能中断 | 3.9.2 |
| DMB | 数据存储屏障 | 3.9.3 |
| DSB | 数据同步屏障 | 3.9.4 |
| ISB | 指令同步屏障 | 3.9.5 |
| MRS | 特殊寄存器传送到寄存器 | 3.9.6 |
| MSR | 寄存器传送到特殊寄存器 | 3.9.7 |
| NOP | 空操作 | 3.9.8 |
| SEV | 发送事件 | 3.9.9 |
| SVC | 管理程序调用 | 3.9.10 |
| WFE | 等待事件 | 3.9.11 |
| WFI | 等待中断 | 3.9.12 |
3.9.1BKPT
断点。
- 操作数
imm取值 0~255(8 位值)的整数表达式。- 操作
- BKPT 使处理器进入调试状态。调试工具可利用它,在执行到某个特定地址的指令时考察系统状态。处理器忽略 imm;若需要,调试器可以用它保存关于该断点的附加信息。BKPT 指令可放在 IT 块内,但它总是无条件执行,不受 IT 指令所指定条件的影响。
- 条件标志
- 本指令不改变标志。
- 示例
BKPT 0xAB ; 立即数为 0xAB 的断点(调试器可通过 PC 定位并提取该立即数)
3.9.2CPS
改变处理器状态。
- 操作数
effect为:IE 清除特殊寄存器、ID 置位特殊寄存器;iflags为一个或多个标志的序列:i 置位或清除 PRIMASK,f 置位或清除 FAULTMASK。- 操作
- CPS 改变 PRIMASK 与 FAULTMASK 特殊寄存器的值(这两个寄存器的更多信息见 2.3.4 节“异常屏蔽寄存器”)。
- 限制
- 只能在特权软件中使用 CPS,在非特权软件中使用无效;CPS 不能带条件,因此不得用于 IT 块内。
- 条件标志
- 本指令不改变条件标志。
- 示例
CPSID i ; 禁止中断与可配置故障处理(置位 PRIMASK) CPSID f ; 禁止中断与所有故障处理(置位 FAULTMASK) CPSIE i ; 使能中断与可配置故障处理(清除 PRIMASK) CPSIE f ; 使能中断与故障处理(清除 FAULTMASK)
3.9.3DMB
数据存储屏障。
- 操作
- DMB 起数据存储屏障的作用:它保证按程序顺序出现在 DMB 之前的全部显式存储器访问,都在按程序顺序出现在 DMB 之后的显式存储器访问之前完成。DMB 不影响不访问存储器的指令的顺序或执行。
- 条件标志
- 本指令不改变标志。
- 示例
DMB ; 数据存储屏障
3.9.4DSB
数据同步屏障。
- 操作
- DSB 起特殊的数据同步存储器屏障作用:按程序顺序位于 DSB 之后的指令,在 DSB 指令完成之前不会执行。当 DSB 之前的全部显式存储器访问完成时,DSB 指令完成。
- 条件标志
- 本指令不改变标志。
- 示例
DSB ; 数据同步屏障
3.9.5ISB
指令同步屏障。
- 操作
- ISB 起指令同步屏障作用:它冲刷处理器的流水线,使 ISB 之后的全部指令在 ISB 指令完成后,重新从缓存或存储器取指。
- 条件标志
- 本指令不改变标志。
- 示例
ISB ; 指令同步屏障
3.9.6MRS
把特殊寄存器的内容传送到通用寄存器。
- 操作数
spec_reg可以是:APSR、IPSR、EPSR、IEPSR、IAPSR、EAPSR、PSR、MSP、PSP、PRIMASK、BASEPRI、BASEPRI_MAX、FAULTMASK 或 CONTROL。- 操作
- MRS 与 MSR 配合,可作为更新 PSR 的读-改-写序列的一部分,例如清除 Q 标志。在进程切换代码中,必须保存被换出进程的程序员模型状态(包括相关的 PSR 内容),同样必须恢复被换入进程的状态;这些操作用 MRS 组成保存状态的指令序列、用 MSR 组成恢复状态的指令序列。与 MRS 指令配合使用时,BASEPRI_MAX 是 BASEPRI 的别名。
- 限制
- Rd 不能是 SP,也不能是 PC。
- 条件标志
- 本指令不改变标志。
- 示例
MRS R0, PRIMASK ; 读取 PRIMASK 的值并写入 R0
3.9.7MSR
把通用寄存器的内容传送到指定特殊寄存器。
- 操作
- MSR 的寄存器访问操作取决于特权级别:非特权软件只能访问 APSR;特权软件可以访问全部特殊寄存器。在非特权软件中,对 PSR 中未分配位或执行状态位的写入会被忽略。写 BASEPRI_MAX 时,仅在下列情况之一才写入 BASEPRI:Rn 非零且当前 BASEPRI 值为 0;Rn 非零且小于当前 BASEPRI 值。
- 限制
- Rn 不能是 SP,也不能是 PC。
- 条件标志
- 本指令根据 Rn 中的值显式更新标志。
- 示例
MSR CONTROL, R1 ; 读取 R1 的值并写入 CONTROL 寄存器
3.9.8NOP
空操作。
- 操作
- NOP 不做任何事。NOP 不一定是耗时的 NOP:处理器可能在它到达执行阶段之前就把它从流水线中移除。NOP 可用于填充,例如把下一条指令放到 64 位边界上。
- 条件标志
- 本指令不改变标志。
- 示例
NOP ; 空操作
3.9.9SEV
发送事件。
- 操作
- SEV 是一条提示指令,它向多处理器系统中的所有处理器发出事件信号,同时把本地事件寄存器置 1(见 2.5 节“电源管理”)。
- 条件标志
- 本指令不改变标志。
- 示例
SEV ; 发送事件
3.9.10SVC
管理程序调用。
- 操作数
imm取值 0~255(8 位值)的整数表达式。- 操作
- SVC 指令引发 SVC 异常。处理器忽略 imm;若需要,异常处理程序可把它取出来,以确定请求的是哪项服务。
- 条件标志
- 本指令不改变标志。
- 示例
SVC 0x32 ; 管理程序调用(SVC 处理程序可通过压栈的 PC 定位并提取该立即数)
3.9.11WFE
等待事件。
- 操作
- WFE 是一条提示指令。若事件寄存器为 0,WFE 挂起执行,直到发生下列事件之一:出现异常(未被异常屏蔽寄存器或当前优先级屏蔽);若系统控制寄存器中的 SEVONPEND 置位,异常进入挂起状态;若调试已使能,出现调试进入请求;外设或多处理器系统中另一处理器用 SEV 指令发出的事件。若事件寄存器为 1,WFE 把它清 0 并立即返回。详见 2.5 节“电源管理”。
- 条件标志
- 本指令不改变标志。
- 示例
WFE ; 等待事件
3.9.12WFI
等待中断。
- 操作
- WFI 是一条提示指令,它挂起执行,直到发生下列事件之一:出现异常;出现调试进入请求(无论调试是否使能)。
- 条件标志
- 本指令不改变标志。
- 示例
WFI ; 等待中断